StatusBarWait

等待, 直到窗口的状态栏包含指定的字符串.

StatusBarWait , BarText, Timeout, Part#, WinTitle, WinText, Interval, ExcludeTitle, ExcludeText

参数

BarText

如果为空或省略, 该命令等待状态栏变为空白. 否则, 请指定命令将等待出现的文本或部分文本. 文本区分大小写, 匹配行为由 SetTitleMatchMode 决定, 类似于下面的 WinTitle.

要等待状态栏文本 改变, 请在循环中使用 StatusBarGetText, 或像本页底部的例子那样使用 RegEx.

Timeout

如果为空或省略, 命令将无限期等待. 否则, 它等待不超过这个秒数的时间. 若要等待比秒更小的时间, 请指定一个浮点数, 例如, 0.25 等待最多 250 毫秒. 指定 0 等同于指定 0.5. 此参数可以是表达式.

Part#

如果为空或省略, 默认为 1, 这部分通常包含了我们感兴趣的文本. 否则, 请指定要获取的状态栏那一部分的编号, 可以为表达式.

WinTitle, WinText, ExcludeTitle, ExcludeText

如果这些都是空白或省略, 将使用上次找到的窗口. 否则, 为 WinTitle 指定窗口标题或其他条件, 来标识目标窗口, 和/或为 WinText 指定目标窗口的单个文本元素的子字符串(由包含的 Window Spy 实用程序显示).

ExcludeTitle 和 ExcludeText 可用于根据标题或文本排除一个或多个窗口. 它们的规范类似于 WinTitle 和 WinText, 除了 ExcludeTitle 不识别除窗口标题之外的任何条件.

窗口标题和文本是区分大小写的. 默认情况下, 不检测隐藏窗口, 而检测隐藏文本元素, 除非使用 DetectHiddenWindows 和 DetectHiddenText 进行更改. 默认情况下, 窗口标题必须以指定的 WinTitle 或 ExcludeTitle 开头才能匹配, 除非使用 SetTitleMatchMode 进行更改.

Interval

如果为空或省略, 默认为 50. 否则, 请指定此命令在等待时对状态栏进行检查的时间间隔(单位为毫秒), 可以为表达式. 默认为 50.

错误处理

[v1.1.04+]: 如果状态栏无法访问, 则此命令会抛出异常. 想了解更多信息, 请参阅运行时错误.

如果在状态栏出现匹配文本前命令超时了, 则 ErrorLevel 被设置为 1. 如果状态栏无法访问, 则它被设置为 2. 成功找到匹配时则被设置为 0.

备注

此命令尝试读取窗口中首个 标准 状态栏(Microsoft 通用控件: msctls_statusbar32). 某些程序使用它们自己的状态栏或微软通用控件的特殊版本. 此命令不支持这样的状态栏.

在大多数时候, 与其在循环中使用 StatusBarGetText, 不如使用 StatusBarWait 来得有效率, 它包含了避免重复调用 StatusBarGetText 形成的高开销的优化.

StatusBarWait 在开始等待匹配前会确定它的目标窗口. 如果那个目标窗口关闭了, 那么此命令会停止等待, 即使存在另一个匹配指定 WinTitle 和 WinText 的窗口.

当此命令处于等待状态时, 可以通过热键, 自定义菜单项或计时器启动新的线程.

相关

StatusBarGetText, WinGetTitle, WinGetText, ControlGetText

示例

if WinExist("Search Results") ; 设置上次找到的窗口以简化后面的代码.
{
    WinActivate
    Send, {tab 2}!o*.txt{enter}  ; 在搜索窗口中, 输入要搜索的模式.
    Sleep, 400  ; 给状态栏时间, 等它改变为 "Searching".
    StatusBarWait, found, 30
    if ErrorLevel
        MsgBox, The command timed out or there was a problem.
    else
        MsgBox, The search successfully completed.
}

SetTitleMatchMode RegEx  ; 接受正则表达式, 以便在下面使用.
if WinExist("A")  ; 设置上次找到的窗口为活动窗口(供下面使用).
{
   StatusBarGetText, OrigText
   StatusBarWait, ^(?!^\Q%OrigText%\E$)  ; 该正则表达式等待文本发生任何变化.
}