SetTimer

以指定的时间间隔自动并重复运行子程序.

SetTimer , Label, PeriodOnOffDelete, Priority

参数

Label

跳转的目标标签, 热键标签或热字串标签的名称, 这样会执行 Label 下的命令, 直到遇到 Return 或 Exit. 和几乎其他所有命令的参数一样, Label 可以为变量引用(例如 %MyLabel%), 此时将使用变量中的名称作为跳转的目标.

[v1.1.01+]: 如果省略, 则使用 A_ThisLabel. 例如, SetTimer,, Off 可以用来在定时子程序中关闭计时器, 当 SetTimer,, 1000 还会更新当前计时器的 Period(周期) 或者对当前正在运行的 label 设置一个新的定时值. [v1.1.24+]: 如果 A_ThisLabel 为空但是当前线程为计时器启动的, 那么就会直接使用这个计时器. 这个特性对于用计时器调用函数或函数对象时非常方便.

[v1.1.20+]: 如果不存在有效的标签名称, 这个参数可以为一个函数的名称, 其参数列表没有强制参数, 如示例 #4), 或者是引用函数对象的单个变量, 如示例 #5. 目前暂不支持其他返回对象的表达式.

注意: 在 [v1.1.24+] 中, 传递空变量或返回空值的表达式被看做一个错误. 这个参数必须为非空的值或完全忽略.

PeriodOnOffDelete

如果为空或省略, 并且计时器不存在, 将创建一个周期为 250. 如果为空或省略, 并且计时器已经存在, 将激活并重置之前的周期, 除非指定了 Priority. 否则, 指定以下参数之一:

Period: 使用该参数的绝对值创建或更新一个计时器, 如同在此计时器执行前必须经过的近似的毫秒数一样. 计时器会被自动启用和重置. 如果 Period 为正数, 计时器会自动重复直到被脚本显式禁用. [v1.0.46.16+]: 如果 Period 为负数, 则计时器仅执行一次. 例如, 指定 -100 , 计时器将在 100 ms 后执行然后关闭, 就像使用了 SetTimer, Label, Off 一样. [v1.1.24+]: 如果 Label 为脚本生成的对象(不是实际的函数或标签), 计时器将在计时器函数返回后自动删除, 除非重新打开定时器. 这使得对象在脚本不再引用它时可以被释放, 但是它也意味着计时器的 Period 和 Priority 都不会保留.

Period 必须为整数, 除非用的是变量或表达式, 在这种情况下, 任何小数部分都被忽略. 周期的绝对值不能大于 4294967295 ms(49.7 天).

On: 以原来的周期重新启用之前禁用的计时器. 如果计时器不存在, 则进行创建(使用默认的周期 250). 计时器也会重置. 如果计时器存在但之前被设为单次运行模式(见上文), 那么它仍然只运行一次.

Off: 禁用现有的计时器.

Delete [v1.1.20+]: 禁止并删除已存在的计时器. 如果计时器已经关联了某个函数对象, 该对象将被释放. 关闭计时器并不会释放该(函数) 对象.

Priority

如果为空或省略, 默认为 0. 否则, 请指定一个介于 -2147483648 和 2147483647 之间的整数(或为表达式) 来表示计时器的优先级. 有关详情, 请参阅线程.

要改变现有计时器的优先级而不影响其他方面, 请留空前一个参数.

备注

计时器很有用, 因为它们是异步运行的, 这意味着它们会以指定的频率(间隔) 运行, 即使脚本正等待窗口, 显示对话框或忙于其他任务的时候. 它们的许多应用实例包括了当用户空闲时(如 A_TimeIdle 反映的那样) 执行一些动作或在不需要的窗口出现时关闭它们.

尽管计时器给人一种脚本同时执行多个任务的错觉, 实际并非如此. 相反地, 定时子程序只是被当作其他线程来处理: 它们可以中断另一个线程或被另一个线程中断, 例如 热键子程序. 有关详情, 请参阅线程.

每当创建或重新启用计时器或用新的 周期 更新计时器时, 它的子程序都不会立即运行, 必须先经过它的 周期 时间. 如果您希望立即开始计时器的首次执行, 请使用 Gosub 来执行计时器的子程序(但是, 这种方式不会像计时器那样启动新线程; 所以诸如 SendMode 的设置不会以它们的默认值开始).

重置: 如果 SetTimer 用于现有的计时器且第二个参数为数字或单词 ON(为空或省略), 则计时器内部的 "上次运行的时间" 会被重置为当前时间; 换句话说, 在经过它的整个周期后子程序才会再次运行.

计时器精度: 由于操作系统中计时系统的精确度, 周期 通常会被向上取整到最近的 10 或 15.6 毫秒的倍数(取决于所安装的硬件和驱动的类型). 例如, 在 Windows NT/2000/XP 中介于 1 和 10(含边界) 的周期, 通常相当于 10 或 15.6. 使用 Loop+Sleep 可以实现更短的延时, 请参阅演示: DllCall+timeBeginPeriod+Sleep.

可靠性: 在以下条件下, 计时器可能无法按预期时间运行:

  1. 其他程序让 CPU 高负载.
  2. 计时器子程序本身在计时器周期到期时仍在运行(定时子程序运行的时间超过它自己的周期), 或者有太多竞争计时器(改变 SetBatchLines 可能有帮助).
  3. 计时器已经被另一个线程中断, 即另一个定时子程序, 热键子程序或自定义菜单项(这可以使用 Critical 避免). 如果这种情况发生了并且中断的线程需要很长时间才能结束, 则在此期间将有效地禁用中断的计时器. 不过, 任何其他计时器会对这个中断首个计时器的线程进行中断来继续运行.
  4. 使用 Critical 或 Thread Interrupt/Priority 后脚本会变成不可中断的. 在这样的时期, 计时器不会运行. 之后, 当脚本恢复可中断时, 任何过时的计时器会尽快运行一次然后恢复到正常的调度.

尽管计时器在脚本挂起时仍会运行, 但是如果当前线程的 Thread NoTimers 正在起作用或者任意线程被暂停时则不会运行. 此外, 当用户通过脚本的菜单(例如托盘图标菜单或菜单栏) 进行导航时它们也不会运行.

因为计时器是通过临时中断脚本当前线程来运行的, 所以它们的子程序应该保持简短(以便很快地结束), 无论何时很长的中断都是不好的.

其他备注: 要在脚本运行期间保持有效的计时器一般应在自动执行段中进行创建. 与之相比, 临时的计时器经常可以在它自己的子程序中禁用(请参阅此页面底部的示例).

每当计时子程序运行时, 它会使用设置(例如 SendMode) 的默认值开始. 这些默认值可以在自动执行段改变.

如果热键的响应时间非常重要(例如在游戏中) 且脚本包含了子程序执行时间超过 5 ms 的计时器, 那么请使用下列命令来避免 15 ms 的延迟. 如果在热键按下时恰好处于计时器线程的不可中断期间, 那么这样的延迟还是会发生.

Thread, Interrupt, 0  ; 让所有的线程总是可中断的.

如果计时器在它的子程序正运行时被禁用, 那么该子程序会继续运行直到完成.

KeyHistory 功能会显示存在的计时器数目以及当前启用的数目.

要让脚本持续运行(例如只包含计时器的脚本), 请使用 #Persistent.

Gosub, Return, 线程, Thread (命令), Critical, IsLabel(), Menu, #Persistent

示例

当不想要的窗口出现时关闭它们.

#Persistent
SetTimer, CloseMailWarnings, 250
return

CloseMailWarnings:
WinClose, Microsoft Outlook, A timeout occured while communicating
WinClose, Microsoft Outlook, A connection to the server could not be established
return

等待特定的窗口出现, 然后通知用户.

#Persistent
SetTimer, Alert1, 500
return

Alert1:
if not WinExist("Video Conversion", "Process Complete")
    return
; 否则:
SetTimer, Alert1, Off  ; 即此处计时器关闭自己.
SplashTextOn, , , The video conversion is finished.
Sleep, 3000
SplashTextOff
return

检测热键的单次, 两次和三次按下. 这样允许热键根据您按下次数的多少执行不同的操作.

#c::
if (winc_presses > 0) ; SetTimer 已经启动, 所以我们记录键击.
{
    winc_presses += 1
    return
}
; 否则, 这是新开始系列中的首次按下. 把次数设为 1 并启动
; 计时器:
winc_presses := 1
SetTimer, KeyWinC, -400 ; 在 400 毫秒内等待更多的键击.
return

KeyWinC:
if (winc_presses = 1) ; 此键按下了一次.
{
    Run, m:\  ; 打开文件夹.
}
else if (winc_presses = 2) ; 此键按下了两次.
{
    Run, m:\multimedia  ; 打开不同的文件夹.
}
else if (winc_presses > 2)
{
    MsgBox, Three or more clicks detected.
}
; 不论触发了上面的哪个动作, 都对 count 进行重置
; 为下一个系列的按下做准备:
winc_presses := 0
return

一个简单的计数器. 使用函数作为计时器子程序.

#Persistent
SetTimer, Tick, 1000

Tick()
{
    static count := 0
    ToolTip % count++
}

一个更复杂的计数器. 使用 方法(method) 作为计时器子程序.

counter := new SecondCounter
counter.Start()
Sleep 5000
counter.Stop()
Sleep 2000

; 一个记录秒数的示例类...
class SecondCounter {
    __New() {
        this.interval := 1000
        this.count := 0
        ; Tick() 有一个隐式参数 "this" 引用一个对象
        ; 所以
        ; 我们需要创建一个封装 "this" 和 Tick 方法的函数来调用:
        this.timer := ObjBindMethod(this, "Tick")
    }
    Start() {
        ; 已知限制: SetTimer 需要一个纯变量引用.
        timer := this.timer
        SetTimer % timer, % this.interval
        ToolTip % "Counter started"
    }
    Stop() {
        ; 在此之前传递一个相同的对象来关闭计时器:
        timer := this.timer
        SetTimer % timer, Off
        ToolTip % "Counter stopped at " this.count
    }
    ; 本例中, 计时器调用了以下方法:
    Tick() {
        ToolTip % ++this.count
    }
}

示例 #5 的备注: