StatusBarWait

等待, 直到窗口的状态栏包含指定的字符串.

StatusBarWait BarText, Timeout, Part#, WinTitle, WinText, Interval, ExcludeTitle, ExcludeText

参数

BarText

类型: 字符串

如果为空或省略, 函数等待状态栏变成空白. 否则, 请指定函数所等待的文本或部分文本. 此文本是区分大小写的, 且匹配行为由 SetTitleMatchMode 决定, 类似于下面的 WinTitle.

若要等待状态栏是否发生了 改变, 可以在循环中使用 StatusBarGetText, 或像本页底部的例子那样使用 RegEx.

Timeout

类型: 整数或浮点数

如果省略, 函数将会无限期等待. 否则, 等待的时间不会超过这个秒数. 若要等待零点几秒, 请指定一个浮点数, 例如, 0.25 表示最多等待 250 毫秒.

Part#

类型: 整数

如果省略, 默认为 1, 这部分通常包含了我们感兴趣的文本. 否则, 请指定要获取的状态栏那一部分的编号.

WinTitle, WinText, ExcludeTitle, ExcludeText

类型: 字符串, 整数或对象

如果这些都是空白或省略, 将使用上次找到的窗口. 否则, 为 WinTitle 指定窗口标题或其他条件, 来标识目标窗口, 和/或为 WinText 指定目标窗口的单个文本元素的子字符串(由包含的 Window Spy 实用程序显示).

ExcludeTitle 和 ExcludeText 可用于根据标题或文本排除一个或多个窗口. 它们的规范类似于 WinTitle 和 WinText, 除了 ExcludeTitle 不识别除窗口标题之外的任何条件.

窗口标题和文本是区分大小写的. 默认情况下, 不检测隐藏窗口, 而检测隐藏文本元素, 除非使用 DetectHiddenWindows 和 DetectHiddenText 进行更改. 默认情况下, 窗口标题的任意位置包含 WinTitle 或 ExcludeTitle 就能形成匹配, 除非使用 SetTitleMatchMode 进行了更改.

Interval

类型: 整数

如果省略, 默认为 50. 否则, 请指定此函数在等待时对状态栏进行检查的时间间隔(单位为毫秒).

返回值

类型: 整数(布尔值)

如果找到匹配, 该函数返回 1(true), 如果函数超时, 则返回 0(false).

错误处理

如果找不到目标窗口或不包含标准状态栏, 则抛出 TargetError.

如果在发送 SB_GETPARTS 消息时出现问题, 或者在 2000 ms 内没有收到回复, 或在拥有状态栏的进程中无法分配内存, 则抛出 OSError.

备注

该函数尝试读取窗口中首个 标准 状态栏(Microsoft 通用控件: msctls_statusbar32). 某些程序使用它们自己的状态栏或微软通用控件的特殊版本. 不支持这样的状态栏.

在大多数时候, 与其在循环中使用 StatusBarGetText, 不如使用 StatusBarWait 来得有效率, 因为它避免重复调用 StatusBarGetText 所带来的开销.

StatusBarWait 在开始等待匹配前会确定它的目标窗口. 如果那个目标窗口关闭了, 那么此命令会停止等待, 即使存在另一个匹配指定 WinTitle 和 WinText 的窗口.

当函数处于等待状态时, 可以通过热键, 自定义菜单项或计时器启动新的线程.

StatusBarGetText, WinGetTitle, WinGetText, ControlGetText

示例

在现有的资源管理器/搜索窗口中输入新的搜索模式.

if WinExist("Search Results") ; 设置上次找到的窗口以简化后面的代码.
{
    WinActivate
    Send "{tab 2}!o*.txt{enter}"  ; 在搜索窗口中, 输入要搜索的模式.
    Sleep 400  ; 给状态栏时间, 等它改变为 "Searching".
    if StatusBarWait("found", 30)
        MsgBox "The search successfully completed."
    else
        MsgBox "The function timed out."
}

等待活动窗口的状态栏发生变化.

SetTitleMatchMode "RegEx"  ; 接受正则表达式, 以便在下面使用.
if WinExist("A")  ; 设置上次找到的窗口为活动窗口(供下面使用).
{
    OrigText := StatusBarGetText()
    StatusBarWait "^(?!^\Q" OrigText "\E$)"  ; 该正则表达式等待文本发生任何变化.
}