ListView

目录

• 入门和简单示例
• 参数
• 视图模式: 报告(默认), 图标, 平铺, 小图标和列表.
• 内置方法
• 事件
• 图像列表(把图标添加到 ListView 的方法)
• 备注
• 示例

入门和简单示例

List-View 是由操作系统提供的最精心设计的控件之一. 在其最容易识别的形式中, 它显示一个多行多列组成的表格视图, 最常见的例子是资源管理器的文件和文件夹列表(详细信息视图).

ListView 通常是这样的:

尽管它可能是精细的, 但 ListView 的基本功能也易于使用. 创建 ListView 的语法为:

GuiCtrl := MyGui.Add("ListView", Options, ColumnTitles)
GuiCtrl := MyGui.AddListView(Options, ColumnTitles)

这是一个可运行脚本, 它创建并显示一个 ListView 其中包含用户的 "我的文档" 目录中的文件列表:

; 创建窗口:
MyGui := Gui()

; 创建含名称和大小两列的 ListView:
LV := MyGui.Add("ListView", "r20 w700", ["Name", "Size (KB)"])

; 每当用户双击某行时, 通知脚本:
LV.OnEvent("DoubleClick", LV_DoubleClick)

; 从文件夹中获取文件名列表并把它们放入 ListView:
Loop Files, A_MyDocuments "\*.*"
    LV.Add(, A_LoopFileName, A_LoopFileSizeKB)

LV.ModifyCol()  ; 根据内容自动调整每列的大小.
LV.ModifyCol(2, "Integer")  ; 为了进行排序, 指出列 2 是整数.

; 显示窗口:
MyGui.Show()

LV_DoubleClick(LV, RowNumber)
{
    RowText := LV.GetText(RowNumber)  ; 从行的第一个字段中获取文本.
    ToolTip("You double-clicked row number " RowNumber ". Text: '" RowText "'")
}

参数

Options

Type: String

In addition to the general options and styles, the following are supported or noteworthy:

BackgroundColor: Background color. Specify for Color a color name (see color chart) or RGB value (the 0x prefix is optional). Examples: BackgroundSilver, BackgroundFFDD99. If this option is not present, the ListView initially defaults to the system's default background color. Specifying BackgroundDefault applies the system's default background color (usually white). For example, a ListView can be restored to the default color via LV.Opt("+BackgroundDefault").

CColor: Text color. Specify for Color a color name (see color chart) or RGB value (the 0x prefix is optional). Examples: cRed, cFF2211, c0xFF2211, cDefault.

Checked: Provides a checkbox at the left side of each row. When adding a row, specify the word Check in its options to have the box to start off checked instead of unchecked. The user may either click the checkbox or press the spacebar to check or uncheck a row.

CountN: Specify for N the total number of rows that the ListView will ultimately contain. This is not a limit: rows beyond the count can still be added. Instead, this option serves as a hint to the control that allows it to allocate memory only once rather than each time a row is added, which greatly improves row-adding performance (it may also improve sorting performance). To improve performance even more, use LV.Opt("-Redraw") prior to adding a large number of rows and LV.Opt("+Redraw") afterward. See Redraw for more details.

Grid: Provides horizontal and vertical lines to visually indicate the boundaries between rows and columns.

Hdr: Specify -Hdr (minus Hdr) to omit the header (the special top row that contains column titles). To make it visible later, use LV.Opt("+Hdr").

Icon, Tile, IconSmall, List, or Report: See View Modes for details.

LVn: Specify for n the number of an extended ListView style. These styles are entirely separate from generic extended styles. For example, specifying -E0x200 would remove the generic extended style WS_EX_CLIENTEDGE to eliminate the control's default border. By contrast, specifying -LV0x20 would remove LVS_EX_FULLROWSELECT.

LV0x10: Specify -LV0x10 to prevent the user from dragging column headers to the left or right to reorder them. However, it is usually not necessary to do this because the physical reordering of columns does not affect the column order seen by the script. For example, the first column will always be column 1 from the script's point of view, even if the user has physically moved it to the right of other columns.

LV0x20: Specify -LV0x20 to require that a row be clicked at its first field to select it (normally, a click on any field will select it). The advantage of this is that it makes it easier for the user to drag a rectangle around a group of rows to select them.

Multi: Specify -Multi (minus Multi) to prevent the user from selecting more than one row at a time.

NoSortHdr: Prevents the header from being clickable. It will take on a flat appearance rather than its normal button-like appearance. Unlike most other ListView styles, this one cannot be changed after the ListView is created.

NoSort: Turns off the automatic sorting that occurs when the user clicks a column header. However, the header will still behave visually like a button (unless the NoSortHdr option has been specified). In addition, the ColClick event is still raised, so the script can respond with a custom sort or other action.

ReadOnly: Specify -ReadOnly (minus ReadOnly) to allow editing of the text in the first column of each row. To edit a row, select it then press F2 (see the WantF2 option below). Alternatively, you can click a row once to select it, wait at least half a second, then click the same row again to edit it.

Sort: The control is kept alphabetically sorted according to the contents of the first column.

SortDesc: Same as above except in descending order.

WantF2: Specify -WantF2 (minus WantF2) to prevent F2 from editing the currently focused row. This setting is ignored unless -ReadOnly is also in effect.

Wn: Sets the width of the control. For example, specifying w400 would make the control 400 pixels wide. If omitted, the default is 30 times the current font size.

Rn or Hn: Sets the height of the control. For example, specifying r7 would make room for 7 rows inside the control, while h400 would set the total height of the control to 400 pixels. If both R and H are omitted, the default is 5 rows. If the ListView is created with a view mode other than report view, the control is sized to fit rows of icons instead of rows of text. Note that adding icons to a ListView's rows will increase the height of each row, which will make this option inaccurate.

(Unnamed numeric styles): Since styles other than the above are rarely used, they do not have names. See the ListView styles table for a list.

ColumnTitles

Type: Array

An array of column titles such as ["Red", "Green", "Blue"], which form the header of the ListView.

视图模式

ListView 有五种视图模式, 其中最常见的是报告视图(这是默认的). 要使用其他某种视图, 请在 Options 中指定它的名称. 还可以在控件创建后改变视图模式; 例如: LV.Opt("+IconSmall").

Icon: 显示大图标视图. 在该视图和除 Report 之外的所有其他视图中, 除第一列之外的其他列中的文本是不可见的. 要在这种模式下显示图标, 必须有一个大图标 ImageList 分配给它.

Tile: 显示大图标视图, 但具有人体工学差异, 例如每项的文本显示在图标的右边而不是下面. Checkbox 在此视图中不起作用.

IconSmall: 显示小图标视图.

List: 以列表格式显示小图标视图, 其中图标显示在列中. 列数取决于控件的宽度和其中最宽的文本项的宽度.

Report: 切换回报告视图, 这是最初的默认模式. 例如: LV.Opt("+Report").

内置方法

In addition to the default methods/properties of a GUI control, this control type has the following methods.

When the phrase "row number" is used on this page, it refers to a row's current position within the ListView. The top row is 1, the second row is 2, and so on. After a row is added, its row number tends to change due to sorting, deleting, and inserting of other rows. Therefore, to locate specific row(s) based on their contents, it is usually best to use the GetText method in a loop.

行的方法:

• Add: 添加新行到列表底部.
• Insert: 在指定行号插入一个新行.
• Modify: 修改行的属性和/或文本.
• Delete: 删除指定行或所有行.

列的方法:

• ModifyCol: 修改指定列和标题的属性和/或文本.
• InsertCol: 在指定列号插入一个新列.
• DeleteCol: 删除指定的列及其中所有内容.

检索方法:

• GetCount: 返回控件中行或列的总数.
• GetNext: 返回下一个选择, 选中或具有焦点的行的行号.
• GetText: 检索指定行号和列号的文本.

其他方法:

• SetImageList: 设置或替换用于显示图标的 ImageList.

RowNumber := LV.Add(Options, Col1, Col2, ...)

RowNumber := LV.Insert(RowNumber , Options, Col1, Col2, ...)

LV.Modify(RowNumber , Options, NewCol1, NewCol2, ...)

LV.Delete(RowNumber)

LV.ModifyCol(ColumnNumber, Options, ColumnTitle)

ColumnNumber := LV.InsertCol(ColumnNumber, Options, ColumnTitle)

LV.DeleteCol(ColumnNumber)

Count := LV.GetCount(Mode)

Loop LV.GetCount()
{
    RetrievedText := LV.GetText(A_Index)
    if InStr(RetrievedText, "some filter text")
        LV.Modify(A_Index, "Select")  ; 选择首个字段包含过滤文本的所有行.
}

Loop LV.GetCount("Column")
{
    ColWidth := SendMessage(0x101D, A_Index - 1, 0, LV)  ; 0x101D 是 LVM_GETCOLUMNWIDTH.
    MsgBox("Column " A_Index "'s width is " ColWidth ".")
}

RowNumber := LV.GetNext(StartingRowNumber, RowType)

RowNumber := 0  ; 这样使得首次循环从列表的顶部开始搜索.
Loop
{
    RowNumber := LV.GetNext(RowNumber)  ; 在前一次找到的位置后继续搜索.
    if not RowNumber  ; 上面返回零, 所以选择的行已经都找到了.
        break
    Text := LV.GetText(RowNumber)
    MsgBox('The next selected row is #' RowNumber ', whose first field is "' Text '".')
}

ItemState := SendMessage(0x102C, RowNumber - 1, 0xF000, LV)  ; 0x102C 是 LVM_GETITEMSTATE. 0xF000 是 LVIS_STATEIMAGEMASK.
IsChecked := (ItemState >> 12) - 1  ; 如果 RowNumber 为选中的则设置 IsChecked 为真, 否则为假.

Text := LV.GetText(RowNumber , ColumnNumber)

PrevImageListID := LV.SetImageList(ImageListID , IconType)

事件

以下事件可以通过调用 GuiControl.OnEvent 来注册一个回调函数或方法来检测:

额外的(很少使用的) 通知可以通过使用 GuiControl.OnNotify 来检测. 这些通知在 Microsoft Docs 上都有文档. Microsoft Docs 没有显示每个通知代码的数值; 这些可以在 Windows SDK 中找到, 或者在互联网上搜索.

ImageList(图像列表)

图像列表是存储在内存中的一组相同大小的图标. 在创建时, 每个图像列表是空的. 脚本重复调用 IL_Add 来添加图标到列表中, 且给每个图标分配一个序号, 序号从 1 开始. 脚本引用此编号在一行中或列标题中显示一个特定的图标. 这是个可运行示例, 其中演示了如何在 ListView 的行中显示图标:

MyGui := Gui()  ; 创建 Gui 窗口.
LV := MyGui.Add("ListView", "h200 w180", ["Icon & Number", "Description"])  ; 创建 ListView.
ImageListID := IL_Create(10)  ; 创建加载 10 个小图标的图像列表.
LV.SetImageList(ImageListID)  ; 把上面的图像列表指定给当前的 ListView.
Loop 10  ; 把 DLL 中的一系列图标装入图像列表.
    IL_Add(ImageListID, "shell32.dll", A_Index) 
Loop 10  ; 在 ListView 中添加行(出于演示的目的, 每个图标一行).
    LV.Add("Icon" . A_Index, A_Index, "n/a")
MyGui.Show()

ImageList functions:

• IL_Create: Creates a new ImageList that is initially empty.
• IL_Add: Adds an icon or picture to the specified ImageList.
• IL_Destroy: Deletes the specified ImageList.

IL_Create

创建一个新的初始为空的图像列表.

ImageListID := IL_Create(InitialCount, GrowCount, LargeIcons)

参数

InitialCount

类型: 整数

如果省略, 默认为 2. 否则, 请指定希望立即放入列表的图标数量.

GrowCount

类型: 整数

如果省略, 默认为 5. 否则, 请指定每次超过当前列表容量时, 列表将增加的图标数量.

LargeIcons

类型: 布尔值

如果省略, 则默认为 false.

如果为 false, ImageList 将包含小图标.

如果为 true, ImageList 将包含大图标.

添加到列表中的图标自动进行缩放, 以符合系统中大小图标的尺寸.

返回值

类型: 整数

成功时, 函数返回新创建的图像列表的唯一 ID. 失败时, 返回 0.

IL_Add

添加图标或图片到指定的图像列表.

IconIndex := IL_Add(ImageListID, IconFileName , IconNumber)
IconIndex := IL_Add(ImageListID, PicFileName, MaskColor, Resize)

参数

ImageListID

类型: 整数

之前调用 IL_Create 返回的 ID 号.

IconFileName

类型: 字符串

图标(.ICO), 光标(.CUR) 或动画光标(.ANI) 文件的名称(动态光标在 ListView 中显示时实际将不会动), 或图标句柄 , 如 "HBITMAP:" handle. 图标的其他来源包含下列类型的文件: EXE, DLL, CPL, SCR, 以及包含图标资源的其他类型.

IconNumber

类型: 整数

如果省略, 默认为 1(第一个图标组). 否则, 请指定请指定文件中要使用的图标组的编号. 如果为负数, 则假定其绝对值表示可执行文件中图标的资源 ID. 在下面的例子中, 将使用第二个图标组中的默认图标: IL_Add(ImageListID, "C:\My Application.exe", 2).

PicFileName

类型: 字符串

非图标图像的名称, 例如 BMP, GIF, JPG, PNG, TIF, Exif, WMF 和 EMF, 或位图句柄, 如 "HBITMAP:" handle.

MaskColor

类型: 整数

屏蔽的/透明的颜色编码. 对于大多数图片, 0xFFFFFF(白色) 可能是最佳的.

Resize

类型: 布尔值

如果为 true, 则图片缩放为单个图标.

如果为 false, 则图片将被分割为多个可以匹配实际宽度的图标.

返回值

类型: 整数

成功时, 函数返回新图标的索引(首个图标索引为 1, 第二个为 2, 依此类推). 失败时, 返回 0.

IL_Destroy

删除指定的图像列表.

IsDestroyed := IL_Destroy(ImageListID)

参数

ImageListID

类型: 整数

之前调用 IL_Create 返回的 ID 号.

返回值

类型: 整数(布尔值)

成功时, 函数返回 1(true). 失败时, 返回 0(false).

备注

通常没必要销毁图像列表, 因为一旦关联到 ListView, 当 ListView 或其父窗口销毁时它们会被自动销毁. 但是, 如果一个 ListView 和其他 ListView 共享图像列表(通过在 Options 中包含 0x40), 在所有使用此图像列表的 ListView 销毁后脚本应该显式地销毁它. 同样地, 如果脚本使用一个新的图像列表代替 ListView 中原来的, 则应该显式销毁原来的图像列表.

备注

Gui.Submit 对 ListView 控件没有效果.

在对某个列进行排序后 -- 通过用户点击其标题或脚本调用 LV.ModifyCol(1, "Sort") -- 任何随后添加的行将出现在列表的底部而不会遵循排序顺序. 例外情况是 Sort 和 SortDesc 样式, 它们会把新添加的行移动正确的位置.

当 ListView 拥有焦点时如果要检测到用户是否按下 Enter 键, 请使用默认按钮(如果需要则可以隐藏它). 例如:

MyGui.Add("Button", "Hidden Default", "OK").OnEvent("Click", LV_Enter)
...
LV_Enter(*) {
    global
    if MyGui.FocusedCtrl != LV
        return
    MsgBox("Enter was pressed. The focused row number is " LV.GetNext(0, "Focused"))
}

使用键盘除了在行与行之间导航外, 用户还可以通过输入首列中一个项目名称的前几个字符来进行增量搜索. 这使得选择对象跳转到最近匹配的行.

尽管 ListView 中的每个字段可以存储任意长度的文本, 但仅显示开始的 260 个字符.

尽管 ListView 中可以使用的最大行数仅受系统可用内存的限制, 但参照 Count 选项中描述的方法可以极大地提高添加行的性能.

可以使用图片作为 ListView 周围的背景(即作为 ListView 的框架). 要实现这个效果, 请在 ListView 后创建图片控件并且在图片控件的 Options 中包含 0x4000000(这是 WS_CLIPSIBLINGS).

脚本可以在每个窗口中创建多个 ListView.

最好不要使用 SendMessage 直接插入或删除列. 这是因为程序为每个列维护一个排序参数集, 而这会让它们无法同步. 作为替代, 请使用内置的列的方法.

要对 ListView 执行一些操作(例如调整大小, 隐藏或改变字体), 请参阅 GuiControl 对象.

要从外部 ListView(那些不属于脚本自身的) 中提取文本, 请使用 ListViewGetContent.

相关

TreeView, 其他控件类型, Gui, ContextMenu 事件, Gui 对象, GuiControl 对象, ListView 样式列表

示例

LV.Modify(0, "Select")   ; 选择所有行.
LV.Modify(0, "-Select")  ; 取消选择所有行.
LV.Modify(0, "-Check")  ;取消选中所有复选框.

LV.ModifyCol()  ; 此模式不需要参数.

; 创建 GUI 窗口:
MyGui := Gui("+Resize")  ; 允许用户最大化窗口或拖动来改变窗口的大小.

; 创建一些按钮:
B1 := MyGui.Add("Button", "Default", "Load a folder")
B2 := MyGui.Add("Button", "x+20", "Clear List")
B3 := MyGui.Add("Button", "x+20", "Switch View")

; 创建 ListView 及其列:
LV := MyGui.Add("ListView", "xm r20 w700", ["Name", "In Folder", "Size (KB)", "Type"])
LV.ModifyCol(3, "Integer")  ; 为了排序, 表示 Size 列中的内容是整数.

; 创建图像列表, 这样 ListView 才可以显示图标:
ImageListID1 := IL_Create(10)
ImageListID2 := IL_Create(10, 10, true)  ; 搭配小图标列表的大图标列表.

; 将图像列表附加到 ListView 上, 这样它就可以在以后显示图标:
LV.SetImageList(ImageListID1)
LV.SetImageList(ImageListID2)

; 应用控件事件:
LV.OnEvent("DoubleClick", RunFile)
LV.OnEvent("ContextMenu", ShowContextMenu)
B1.OnEvent("Click", LoadFolder)
B2.OnEvent("Click", (*) => LV.Delete())
B3.OnEvent("Click", SwitchView)

; 应用窗口事件:
MyGui.OnEvent("Size", Gui_Size)

; 创建弹出式菜单, 作为上下文菜单使用:
ContextMenu := Menu()
ContextMenu.Add("Open", ContextOpenOrProperties)
ContextMenu.Add("Properties", ContextOpenOrProperties)
ContextMenu.Add("Clear from ListView", ContextClearRows)
ContextMenu.Default := "Open"  ; 将 "Open(打开)" 改为粗体字, 以表明这是双击的默认动作.

; 显示窗口:
MyGui.Show()

LoadFolder(*)
{
    static IconMap := Map()
    MyGui.Opt("+OwnDialogs") ; 强制用户在使用主窗口之前关闭下面的对话框.
    Folder := DirSelect(, 3, "Select a folder to read:")
    if not Folder  ; 用户取消对话框.
        return

    ; 检查文件夹名称的最后一个字符是否为反斜杠, 对于根目录则会如此,
    ; 例如 C:\. 如果是, 则移除这个反斜杠以避免之后出现两个反斜杠.
    if SubStr(Folder, -1, 1) = "\"
        Folder := SubStr(Folder, 1, -1)  ; 移除尾部的反斜杠.

    ; 计算 SHFILEINFO 结构需要的缓冲大小.
    sfi_size := A_PtrSize + 688
    sfi := Buffer(sfi_size)

    ; 获取所选择文件夹中的文件名列表并添加到 ListView:
    LV.Opt("-Redraw")  ; 在加载时禁用重绘来提升性能.
    Loop Files, Folder "\*.*"
    {
        FileName := A_LoopFilePath  ; 必须保存到可写的变量中供后面使用.

        ; 建立唯一的扩展 ID 以避免变量名中的非法字符,
        ; 例如破折号. 这种使用唯一 ID 的方法也会执行地更好,
        ; 因为在数组中查找项目不需要进行搜索循环.
        SplitPath(FileName,,, &FileExt)  ; 获取文件扩展名.
        if FileExt ~= "i)\A(EXE|ICO|ANI|CUR)\z"
        {
            ExtID := FileExt  ; 特殊 ID 作为占位符.
            IconNumber := 0  ; 将其标记为未找到, 以便这些类型可以有一个唯一的图标.
        }
        else  ; 其他的扩展名/文件类型, 计算它们的唯一 ID.
        {
            ExtID := 0  ; 进行初始化来处理比其他更短的扩展名.
            Loop 7     ; 限制扩展名为 7 个字符, 这样之后计算的结果才能存放到 64 位值.
            {
                ExtChar := SubStr(FileExt, A_Index, 1)
                if not ExtChar  ; 没有更多字符了.
                    break
                ; 把每个字符与不同的位置进行运算来得到唯一 ID:
                ExtID := ExtID | (Ord(ExtChar) << (8 * (A_Index - 1)))
            }
            ; 检查此文件扩展名的图标是否已经在图像列表中. 如果是,
            ; 可以避免多次调用并极大提高性能,
            ; 尤其对于包含数以百计文件的文件夹而言:
            IconNumber := IconMap.Has(ExtID) ? IconMap[ExtID] : 0
        }
        if not IconNumber  ; 此扩展名还没有相应的图标, 所以进行加载.
        {
            ; 取与此文件扩展名关联的高质量小图标:
            if not DllCall("Shell32\SHGetFileInfoW", "Str", FileName
            , "Uint", 0, "Ptr", sfi, "UInt", sfi_size, "UInt", 0x101)  ; 0x101 是 SHGFI_ICON+SHGFI_SMALLICON
                IconNumber := 9999999  ; 把它设置到范围外来显示空图标.
            else ; 成功加载图标.
            {
                ; 从结构中提取 hIcon 成员:
                hIcon := NumGet(sfi, 0, "Ptr")
                ; 直接添加 HICON 到小图标和大图标列表.
                ; 下面加上 1 来把返回的索引从基于零转换到基于一:
                IconNumber := DllCall("ImageList_ReplaceIcon", "Ptr", ImageListID1, "Int", -1, "Ptr", hIcon) + 1
                DllCall("ImageList_ReplaceIcon", "Ptr", ImageListID2, "Int", -1, "Ptr", hIcon)
                ; 现在已经把它复制到图像列表, 所以应销毁原来的:
                DllCall("DestroyIcon", "Ptr", hIcon)
                ; 缓存图标来节省内存并提升加载性能:
                IconMap[ExtID] := IconNumber
            }
        }

        ; 在 ListView 中创建新行并把它和上面的图标编号进行关联:
        LV.Add("Icon" . IconNumber, A_LoopFileName, A_LoopFileDir, A_LoopFileSizeKB, FileExt)
    }
    LV.Opt("+Redraw")  ; 重新启用重绘(上面把它禁用了).
    LV.ModifyCol()  ; 根据内容自动调整每列的大小.
    LV.ModifyCol(3, 60)  ; 把 Size 列加宽一些以便显示出它的标题.
}

SwitchView(*)
{
    static IconView := false
    if not IconView
        LV.Opt("+Icon")        ; 切换到图标视图.
    else
        LV.Opt("+Report")      ; 切换回详细信息视图.
    IconView := not IconView   ; 进行反转以为下次做准备.
}

RunFile(LV, RowNumber)
{
    FileName := LV.GetText(RowNumber, 1) ; 获取首个字段的文本.
    FileDir := LV.GetText(RowNumber, 2)  ; 获取第二个字段的文本.
    try
        Run(FileDir "\" FileName)
    catch
        MsgBox("Could not open " FileDir "\" FileName ".")
}

ShowContextMenu(LV, Item, IsRightClick, X, Y)  ; 响应右键或 Apps 键.
{
    ; 在所提供的 X 和 Y 坐标处显示菜单.
    ; 这些应该被使用, 因为即使用户按了 Apps 键, 它们也能提供正确的坐标:
    ContextMenu.Show(X, Y)
}

ContextOpenOrProperties(ItemName, *)  ; 用户在上下文菜单中选择了 "Open" 或 "Properties".
{
    ; 简单地说, 只对焦点行进行操作, 而不是对所有选中的行进行操作:
    FocusedRowNumber := LV.GetNext(0, "F")  ; 查找焦点行.
    if not FocusedRowNumber  ; 没有聚焦行.
        return
    FileName := LV.GetText(FocusedRowNumber, 1) ; 获取首个字段的文本.
    FileDir := LV.GetText(FocusedRowNumber, 2)  ; 获取第二个字段的文本.
    try
    {
        if (ItemName = "Open")  ; 用户在上下文菜单中选择了 "Open".
            Run(FileDir "\" FileName)
        else
            Run("properties " FileDir "\" FileName)
    }
    catch
        MsgBox("Could not perform requested action on " FileDir "\" FileName ".")
}

ContextClearRows(*)  ; 用户在上下文菜单中选择了 "Clear".
{
    RowNumber := 0  ; 这会使得首次循环从顶部开始搜索.
    Loop
    {
        ; 由于删除了一行使得此行下面的所有行的行号都减小了,
        ; 所以把行号减 1, 这样搜索里包含的行号才会与之前找到的行号相一致
        ; (以防选择了相邻行):
        RowNumber := LV.GetNext(RowNumber - 1)
        if not RowNumber  ; 上面返回零, 所以没有更多选择的行了.
            break
        LV.Delete(RowNumber)  ; 从 ListView 中删除行.
    }
}

Gui_Size(thisGui, MinMax, Width, Height)  ; 扩大或缩小 ListView 来响应用户对窗口大小的改变.
{
    if MinMax = -1  ; 窗口被最小化了. 无需进行操作.
        return
    ; 否则, 窗口的大小被调整过或被最大化了. 调整 ListView 的大小来适应.
    LV.Move(,, Width - 20, Height - 40)
}