HotIf / HotIfWin...

指定后续创建或修改热键变体和热字串变体的条件.

目录:

HotIf

HotIf "Expression"
HotIf Callback

参数

"Expression"

类型: 字符串

如果省略, 将设置空白条件(关闭上下文相关性). 否则, 条件将被设置为现有的 #HotIf 表达式. 表达式通常写成一个加引号字符串, 但也可以是一个返回与 #HotIf 表达式匹配的文本的变量或表达式.

注意: HotIf 函数使用你传递给它的字符串, 而不是原始源代码. 当脚本加载时, 转义序列会被解析, 所以只考虑结果字符; 例如, HotIf 'x = "`t"' 和 HotIf 'x = "' A_Tab '"' 都对应于 #HotIf x = "`t".

有关示例, 请参阅 #HotIf 示例 #5.

Callback

类型: 函数对象

如果省略, 设置空白条件(关闭上下文相关性). 否则, 为给定的函数对象设置条件. 随后创建的热键和热字串只有在调用给定的函数对象产生一个非零的数字时才会执行. 这类似于 HotIf "Expression", 只不过每个热键和热字串可以有很多热键变体或热字串变体(每个对象一个).

回调函数接受一个参数, 定义如下:

MyCallback(HotkeyName) { ...

尽管您给参数的名称并不重要, 但它被赋值为热键名称或热字串名称.

如果不需要相应的信息, 可以省略回调参数, 但在这种情况下必须指定星号, 例如 MyCallback(*).

一旦传递给 HotIf 函数, 该对象将永远不会被删除(但进程退出时, 内存将被操作系统回收).

有关示例, 请参阅下面的示例 #2 或 Hotkey 的示例 #6.

HotIfWin...

HotIfWinActive WinTitle, WinText
HotIfWinExist WinTitle, WinText
HotIfWinNotActive WinTitle, WinText
HotIfWinNotExist WinTitle, WinText

参数

WinTitle, WinText

类型: 字符串

如果省略这两个选项, 将设置空白条件(关闭上下文相关性). 否则, 为 WinTitle 指定 窗口标题和其他条件, 以标识目标窗口和/或为 WinText 指定目标窗口的单个文本元素的子字符串(如同包含的 window Spy 实用程序显示的那样). 根据所调用的函数, 受影响的热键和热字串仅在目标窗口处于活动状态, 存在, 处于不活动状态, 或不存在时才有效.

由于参数在函数被调用之前就已经被计算了, 因此任何变量引用都会在那一刻成为永久性的. 换句话说, 变量内容的后续变化不会被现有的热键和热字串看到.

WinTitle 和 WinText 的含义与 WinActive 或 WinExist 中的相同, 但是只能使用字符串, 并且它们的计算与自动执行线程设置的 SetTitleMatchMode 和 DetectHiddenWindows 的默认设置一致.

有关示例, 请参阅下面的示例 #1.

错误处理

如果 HotIf 的参数无效, 例如它不匹配现有的表达式, 或不是一个有效的回调函数, 则抛出异常.

备注

HotIf 和 HotIfWin 函数允许在脚本运行时创建和修改上下文相关的热键和热字串(相比之下, #HotIf 指令是位置性的, 在脚本开始执行前生效). 例如:

HotIfWinActive "ahk_class Notepad"
Hotkey "^!e", MyFuncForNotepad  ; 创建一个只在记事本中工作的热键.

使用 HotIf 或其中一个 HotIfWin 函数会使当前线程中把所有随后创建或修改的热键都变成上下文相关的, 并影响 Hotkey 或 Hotstring 函数修改的热键或热字串变体. 只有最近一次对当前线程中任何 HotIf 或 HotIfWin 函数的调用才会生效.

要关闭上下文相关性(也就是说, 使后续创建的热键和 热字串在所有窗口中工作), 调用任意 HotIf 或其中一个 HotIfWin 函数, 但省略参数. 例如: HotIf 或 HotIfWinActive.

在热键或热字串线程中使用 HotIf 或其中一个 HotIfWin 之前, Hotkey 和 Hotstring 函数默认与启动该线程的热键或热串的上下文相同. 换句话说, Hotkey A_ThisHotkey, "Off" 关闭当前热键, 即使它是上下文相关的. 所有其他线程都默认创建或修改全局热键或热字串, 除非在脚本启动时使用 HotIf 或其中一个 HotIfWin 覆盖了该默认值.

使用 HotIf, 其中一个 HotIfWin, 或 #HotIf 指令禁用鼠标或键盘热键后, 它会执行其原来的功能; 也就是说, 它传递到活动窗口, 就好像不存在热键一样. 然而, 控制器热键总是有效, 无论禁用与否.

热键, 热字串, Hotkey 函数, Hotstring 函数, #HotIf, 线程

示例

与 #HotIf 的示例 #1 类似, 这创建了两个热键和一个热字串, 一个热键仅在记事本处于活动状态时有效, 另一个热键适用于除记事本以外的任何窗口. 主要区别在于, 这个示例在运行时创建了与上下文相关的热键和热字串, 而 #HotIf 的示例在加载时创建它们.

HotIfWinActive "ahk_class Notepad"
Hotkey "^!a", ShowMsgBox
Hotkey "#c", ShowMsgBox
Hotstring "::btw", "This replacement text will occur only in Notepad."
HotIfWinActive
Hotkey "#c", (*) => MsgBox("You pressed Win-C in a window other than Notepad.")

ShowMsgBox(HotkeyName)
{
    MsgBox "You pressed " HotkeyName " while Notepad is active."
}

与上面的例子类似, 但是使用了回调.

HotIf MyCallback
Hotkey "^!a", ShowMsgBox
Hotkey "#c", ShowMsgBox
Hotstring "::btw", "This replacement text will occur only in Notepad."
HotIf
Hotkey "#c", (*) => MsgBox("You pressed Win-C in a window other than Notepad.")

MyCallback(*)
{
    if WinActive("ahk_class Notepad")
        return true
    else
        return false
}

ShowMsgBox(HotkeyName)
{
    MsgBox "You pressed " HotkeyName " while Notepad is active."
}