简单对象 - 关联数组

InsertAt [v1.1.21+]

插入一个或多个值到线性数组中的给定序号位置中.

Object.InsertAt(Pos, Value1 , Value2, ... ValueN)

参数

Pos

要将 Value1 插入到数组中的序号数字. 随后的值将插入到 Pos+1, Pos+2, 等等.

Value1 ...

要插入数组的一个或多个值. 要将另一个数组中的值一次性插入, 传递 theArray* 作为最后一个参数.

备注

InsertAt 对应的是 RemoveAt.

作为关联数组对象, Pos 的整数值同时也成为 Value1 在数组对象中的键名. 位于 Pos 之前或之后的键值对都会被自动改为正确的对应关系数值, 哪怕键对应的值不存在也是如此(因为对象是稀疏数组). 例如:

x := []
x.InsertAt(1, "A", "B") ; =>  ["A", "B"]
x.InsertAt(2, "C")      ; =>  ["A", "C", "B"]

; 稀疏(不连续)/未赋值元素也被保留:
x := ["A", , "C"]
x.InsertAt(2, "B")      ; =>  ["A", "B",    , "C"]

x := ["C"]
x.InsertAt(1, , "B")    ; =>  [   , "B", "C"]

InsertAt 最好仅用于处理对象中的整数键表示线性数组中位置的情况. 如果对象中包含不连续的任意值整数键, 比如 ID(不连续的序号) 或 handles(句柄), InsertAt 会产生出乎意料的效果. 例如:

x := [], handleX := 0x4321, handleY := 0x1234
x.InsertAt(handleX, "A")
MsgBox % x[handleX]  ; A - 正确
x.InsertAt(handleY, "B")
MsgBox % x[handleX]  ; 返回空值
MsgBox % x[handleX+1]  ; 这是 "A" 新的 "位置"

InsertAt 不会影响文本或对象键, 所以可以安全的用于混合键类型的对象.

RemoveAt [v1.1.21+]

从线性数组的指定位置移除键值对.

RemovedValue := Object.RemoveAt(Pos)
RemovedItemsCount := Object.RemoveAt(Pos, Length)

参数

Pos

表示要从此处开始删除一个或多个值.

Length

如果省略, 则移除一个项目. 否则, 请指定要删除值的范围. 从 Pos 到 Pos+Length-1 之间的所有值将被删除.

返回值

如果省略 Length, 则返回从 Pos 删除的值(如果没有则为空). 否则, 返回值是已删除的有值项的数量, 它可以不同于稀疏数组中的 Length, 但它总是在 0 和 Length(包括) 之间.

备注

RemoveAt 对应于 InsertAt.

剩下的那些位于 Pos 前后的键值对会根据 Length(或者省略时为 1) 长度强制对齐, 哪怕被删除的范围中不包含任何值. 例如:

x := ["A", "B"]
MsgBox % x.RemoveAt(1)  ; A
MsgBox % x[1]           ; B

x := ["A", , "C"]
MsgBox % x.RemoveAt(1, 2)  ; 1
MsgBox % x[1]              ; C

RemoveAt 最好仅用于处理对象中的整数键表示线性数组中位置的情况. 如果对象中包含不连续的任意值整数键, 比如 ID 或句柄, RemoveAt 会产生出乎意料的效果. 例如:

x := {0x4321: "A", 0x1234: "B"}
MsgBox % x.RemoveAt(0x1234) ; B
MsgBox % x[0x4321]          ; 空
MsgBox % x[0x4321-1]        ; A

RemoveAt 不会影响文本或对象键, 所以可以安全的用于混合键类型的对象.

Push [v1.1.21+]

追加一个或多个值到数组的尾部.

Index := Object.Push(Value, Value2, ..., ValueN)

参数

Value ...

要插入数组的一个或多个值. 要将另一个数组中的值一次性插入, 传递 theArray* 作为最后一个参数.

返回值

此方法返回最后插入值的位置编号. 如果数组只包含负数索引的元素, 这个数字可以是负数.

备注

如果数组为空或仅包含字符串或对象键时, 第一个插入的值的位置(索引) 为 1.

其他情况下, 插入的第一个值位于 Object.MaxIndex() + 1, 哪怕那个位置是负数或零. 如果这不是您预期的结果, 对于含有负数键的对象也可以这样 Object.InsertAt(Object.Length() + 1, ...) .

Pop [v1.1.21+]

删除并返回数组中最后一个数组元素.

RemovedValue := Object.Pop()

如果该数组中不含有任何元素, 返回值为空字符串. 其他情况下, 它相当于:

RemovedValue := Object.RemoveAt(Object.Length())

Delete [v1.1.21+]

删除对象中的键-值对.

RemovedValue := Object.Delete(Key)
RemovedItemsCount := Object.Delete(FirstKey, LastKey)

参数

Key

任意一个键.

FirstKey, LastKey

任意有效的整数范围或字符串键, 其中 FirstKey <= LastKey. 两个键必须是相同的类型.

返回值

如果只有一个参数, 将返回被删除的值(如果不存在则返回空值). 其他情况将返回范围中存在并被删除的键的计数.

备注

与 RemoveAt 不同的是, Delete 不会影响任何没有被删除的键-值对(译者注: 仅删除值, 而保留键位). 例如:

x := ["A", "B"]
MsgBox % x.RemoveAt(1)  ; A
MsgBox % x[1]           ; B

x := ["A", "B"]
MsgBox % x.Delete(1)    ; A
MsgBox % x[1]           ; 为空

MinIndex / MaxIndex [AHK_L 31+]

如果存在, 则返回最小或最大整数键.

MinIndex := Object.MinIndex()
MaxIndex := Object.MaxIndex()

如果没有整数键, 则返回空字符串.

Length [v1.1.21+]

返回线性数组的长度.

Length := Object.Length()

这个方法返回从位置 1 开始的线性数组的长度; 即, 对象所包含的最大正整数键, 如果没有, 则为 0.

MsgBox % ["A", "B", "C"].Length()  ;  3
MsgBox % ["A",    , "C"].Length()  ;  3
MsgBox % {-10: 0, 10: 0}.Length()  ; 10
MsgBox % {-10: 0, -1: 0}.Length()  ;  0

Count [v1.1.29+]

返回一个对象中存在的键值对的个数.

Count := Object.Count()

示例:

MsgBox % {A: 1, Z: 26}.Count()    ;  2
MsgBox % ["A", "B", "C"].Count()  ;  3
MsgBox % ["A",    , "C"].Count()  ;  2

SetCapacity [AHK_L 31+]

调整对象或其一个字段占用的内存空间.

MaxItems := Object.SetCapacity(MaxItems)
ByteSize := Object.SetCapacity(Key, ByteSize)

参数

MaxItems

对象在必须自动扩展前可以包含的键值对的最大数目. 如果少于键值对的当前数目, 则使用该数目并释放未使用的内存.

Key

任何有效键.

ByteSize

为目标字段字符串缓存设置新的大小, 不包括空终止符, 单位为字节. 如果字段不存在, 则创建它. 如果 ByteSize 为零, 则清空缓存但不移除空字段. 如果 ByteSize 小于当前大小, 则移除额外的数据; 否则保留所有现有的数据.

返回值

成功时, 此方法返回新设置的内存空间, 否则为空字符串.

GetCapacity [AHK_L 31+]

返回对象或其一个字段当前占用的内存空间.

MaxItems := Object.GetCapacity()
ByteSize := Object.GetCapacity(Key)

如果字段不存在或不包含字符串, 则返回空字符串.

GetAddress [AHK_L 31+]

返回对象的区域字符串缓冲区地址, 如果它有.

Ptr := Object.GetAddress(Key)

_NewEnum [AHK_L 49+]

返回一个新的枚举器, 用于枚举当前对象中的键值对.

Enum := Object._NewEnum()

该方法通常不直接调用, 而是使用 for-loop 来遍历对象.

HasKey [AHK_L 53+]

如果指定的键在对象中存在(定义) 关联的值(即使值为 ""), 则返回 1(true), 否则为 0(false).

HasKey := Object.HasKey(Key)

Clone [AHK_L 60+]

返回对象的一个浅拷贝(拷贝对象的指针, 而不是对象本身, 引用的内存地址资源相同, 对象引用加 1).

Clone := Object.Clone()

Insert [AHK_L 31+]

插入键值对到对象中, 如果传递的是整数键, 将自动调整现有的键.

Object.Insert(Pos, Value1 , Value2, ... ValueN )
Object.Insert(Value)
Object.Insert(StringOrObjectKey, Value)

Insert 的行为取决于参数的个数和类型::

• 如果传递多个参数且第一个参数为整数, Insert 的行为类似 InsertAt.
• 如果传递多个参数且第一个参数不是整数, Insert 的行为类似 ObjRawSet.
• 如果仅有一个参数, Insert 的行为类似 Push.

Insert 返回 1(true). 在 [v1.1.21+] 中, 当内存申请失败时将抛出异常. 之前的版本返回一个空字符串.

Remove [AHK_L 31+]

从对象中删除键值对.

Object.Remove(FirstKey, LastKey)

Remove 的行为方式取决于其参数的个数和类型:

• Object.Remove(Integer) 表现得就像 Object.RemoveAt(Integer).
• Object.Remove(Integer, "") 表现得就像 Object.Delete(Integer).
• Object.Remove(Integer1, Integer2) 表现得就像 Object.RemoveAt(Integer1, Integer2 - Integer1 + 1).
• Object.Remove() 表现得就像 Object.Pop().
• 其他任何合法的调用时, 表现得就像 Delete.

Base

检索或设置对象的基对象.

BaseObject := Object.Base

Object.Base := BaseObject

BaseObject 必须是对象或空字符串.

基对象定义的属性和方法只有在使用该基对象时才可访问. 因此, 更改 对象 的 base 也会改变可用属性和方法的集合.

参见: ObjGetBase(), ObjSetBase