FileMove

移动或重命名一个或多个文件.

FileMove, SourcePattern, DestPattern , Overwrite

参数

SourcePattern

单个文件的名称或通配符模式, 例如 C:\Temp\*.tmp. 如果未指定绝对路径, 则假定 SourcePattern 在 %A_WorkingDir% 中.

DestPattern

目标的名称或模式, 如果未指定绝对路径, 则假定在 %A_WorkingDir% 中.

如果星号存在, 则将文件名中的第一个星号(*) 替换为不包含其扩展名的源文件名, 而将最后一个句号(.) 后的第一个星号替换为源文件的扩展名. 如果有星号, 但省略了扩展名, 则使用源文件的扩展名.

要执行简单地移动 -- 保留原来的文件名 -- 只需要指定文件夹名, 如下面几乎等同的两个例子所示:

FileMove, C:\*.txt, C:\My Folder

FileMove, C:\*.txt, C:\My Folder\*.*

目标目录必须已经存在. 如果 My Folder 不存在, 上面的第一个示例将使用 "My Folder" 作为目标文件名, 而第二个示例将不移动任何文件.

Overwrite

如果为空或省略, 则默认为 0. 否则, 请指定以下数字之一, 来指示是否覆盖已存在的文件:

0: 不覆盖现有的文件. 如果已经存在以 DestPattern 为名称的文件或目录, 则操作会失败并且没有任何效果.

1: 覆盖现在的文件. 但是, 不会删除在 DestPattern 中没有被 SourcePattern 目录中文件覆盖的其他子目录或文件.

参数可以是表达式, 甚至可以是计算结果为 1, 0 或空字符串的表达式.

错误处理

[v1.1.04+]: 此命令失败时会抛出异常. 想了解更多信息, 请参阅运行时错误.

ErrorLevel 被设置为由于错误而无法移动的文件数, 否则为 0. 但是, 如果源文件为单个文件(没有通配符) 且此文件不存在, 则 ErrorLevel 被置为 0. 要判断这种情况, 请在移动前对源文件使用 FileExist() 或 IfExist.

与 FileCopy 不同, 移动一个文件来覆盖它自己总被认为是成功的, 即使在改写模式没有生效的情况下.

如果找到了文件, 则 A_LastError 会被设置为 0(零) 或最近一次操作失败时调用操作系统 GetLastError() 函数的结果. 否则 A_LastError 包含了没有找到文件原因的错误码.

备注

FileMove 只移动文件. 要移动整个文件夹的内容(它的所有文件和子文件夹), 请参照下面的示例部分. 要移动或重命名单个文件夹, 请使用 FileMoveDir.

在遇到错误后操作仍会继续进行.

尽管此命令可以移动文件到不同的卷, 但这样的操作会比在相同卷上消耗更多的时间. 这是由于在相同卷上类似于重命名, 因此快速得多.

相关

FileCopy, FileCopyDir, FileMoveDir, FileDelete

示例

FileMove, C:\My Documents\List1.txt, D:\Main Backup\

FileMove, C:\File Before.txt, C:\File After.txt

FileMove, C:\Folder1\*.txt, D:\New Folder\*.bkp

ErrorCount := MoveFilesAndFolders("C:\My Folder\*.*", "D:\Folder to receive all files & folders")
if (ErrorCount != 0)
    MsgBox %ErrorCount% files/folders could not be moved.

MoveFilesAndFolders(SourcePattern, DestinationFolder, DoOverwrite = false)
; 移动匹配 SourcePattern 的所有文件和文件夹到 DestinationFolder 文件夹中且
; 返回无法移动的文件/文件夹的数目. 此函数需要 [v1.0.38+]
; 因为它使用了 FileMoveDir 的模式 2.
{
    if (DoOverwrite = 1)
        DoOverwrite := 2  ; 请参阅 FileMoveDir 了解模式 2 与模式 1 的区别.
    ; 首先移动所有文件(不是文件夹):
    FileMove, %SourcePattern%, %DestinationFolder%, %DoOverwrite%
    ErrorCount := ErrorLevel
    ; 现在移动所有文件夹:
    Loop, %SourcePattern%, 2  ; 2 表示 "只获取文件夹".
    {
        FileMoveDir, %A_LoopFileFullPath%, %DestinationFolder%\%A_LoopFileName%, %DoOverwrite%
        ErrorCount += ErrorLevel
        if ErrorLevel  ; 报告每个出现问题的文件夹名称.
            MsgBox Could not move %A_LoopFileFullPath% into %DestinationFolder%.
    }
    return ErrorCount
}