链接 COM 对象的事件到给定的前缀名的响应函数.
ComObjConnect(ComObject , PrefixOrSink)
产生事件的对象.
如果对象不支持 IConnectionPointContainer 接口, 或无法获取对象类的类型信息, 将显示一条错误信息. 可通过 ComObjError() 或 try/catch 禁止或处理此错误信息.
[v1.1.22+]: 如果对象支持, 使用 IProvideClassInfo 接口以接收此对象类的类型信息. 否则, ComObjConnect 尝试通过对象的 IDispatch 接口以接收类型信息, 这可能不可靠.
如果为空或省略, 则对象为 "未连接的"; 即脚本将不再接收其事件通知. 否则, 指定一个作为事件名称前缀的字符串, 用于确定在事件发生时调用哪个函数, 或者 [在 v1.1.01+] 作为事件接收对象(为要处理的每个事件定义方法).
在脚本中编写处理所需事件的函数. 这类函数或 "事件处理程序" 具有下列结构:
PrefixEventName([Params..., ComObject])
{
... 事件处理代码 ...
return ReturnValue
}
如果是字符串, Prefix 应该与 PrefixOrSink 参数相同; 否则, 它应该被省略. EventName 应该替换为函数应该处理的任何事件的名称.
Params(参数) 对应于事件包含的所有参数. 如果事件不含有参数, Params 应完全省略. ComObject 为可选, 仅当 Params 的数目正确时; 它包含了到传递给 ComObjConnect 的原始包装器(转换器) 对象的引用. "ComObject" 应被替换为与您脚本上下文相关的更有意义的名称.
注意, 事件处理程序可以产生返回值. 要返回特定的 COM 类型的值, 使用 ComObject(). 例如, return ComObject(0,0) 返回类型为 VT_EMPTY 的变体, 其等效于从 JavaScript 函数中返回 undefined(或未返回).
调用 ComObjConnect(目标对象, "Prefix") 以启用事件处理.
调用 ComObjConnect(目标对象) 以断开对象(停止事件处理).
如果参数的数目未知, 可用可变参数函数.
如果 PrefixOrSink 是一个对象, 则每当引发事件时, 就会调用该对象的相应方法. 虽然对象可以动态构造, 但 PrefixOrSink 更典型的做法是引用一个类或类的实例. 在这种情况下, 方法的定义如上所示, 但没有 Prefix.
与对方法的任何调用一样, 方法的(通常是隐藏的) this 参数包含对方法调用所通过的对象的引用; 即事件接收器对象, 而不是 COM 对象. 这可用于为事件处理程序提供上下文, 或在它们之间共享值.
要捕获所有事件而不为每个事件定义方法, 请定义 __Call 元函数.
ComObject 保留了对 PrefixOrSink 的引用, 因此在对象断开连接之前不能删除它.
[v1.1.36.02+]: 如果 COM 对象释放连接, ComObject 会自动释放它对 PrefixOrSink 的引用. 例如, Internet Explorer 在退出时就会这样做. 如果脚本不保留自己对 PrefixOrSink 的引用, 它可以使用 __Delete 来检测何时发生这种情况. 如果该对象由远程进程托管, 并且该进程意外终止, 则系统可能需要几分钟才能释放连接.
脚本必须保留对 ComObject 的引用, 否则它将自动释放, 并与其 COM 对象断开连接, 从而阻止任何进一步的事件被检测. 没有标准的方法来检测何时不再需要连接, 因此脚本必须通过调用 ComObjConnect 来手动断开连接.
可能需要使用 #Persistent 指令, 以便在脚本监听事件时保持脚本运行.
失败时, 函数可能会抛出异常, 退出脚本或返回空字符串, 具体取决于当前的 ComObjError() 设置和其他因素.
ComObjCreate(), ComObjGet(), ComObjActive(), ComObjError(), WScript.ConnectObject (Microsoft Docs)
启动 Internet Explorer 的实例, 并将事件连接到相应的前缀为 "IE_" 的脚本函数. 有关 COM 对象和下面使用的 DocumentComplete 事件的详情, 请参阅 InternetExplorer object (Microsoft Docs).
ie := ComObjCreate("InternetExplorer.Application")
; 把事件连接到带 "IE_" 前缀的脚本函数.
ComObjConnect(ie, "IE_")
ie.Visible := true ; 已知此语句在 IE7 上无法正常执行.
ie.Navigate("https://www.autohotkey.com/")
#Persistent
IE_DocumentComplete(ieEventParam, url, ieFinalParam) {
global ie
if (ie != ieEventParam)
s .= "第一个参数是新的包装器对象.`n"
if (ie == ieFinalParam)
s .= "最后一个参数是原始包装器对象.`n"
if ((disp1:=ComObjUnwrap(ieEventParam)) == (disp2:=ComObjUnwrap(ieFinalParam)))
s .= "两个包装器对象均引用同一个 IDispatch 实例.`n"
ObjRelease(disp1), ObjRelease(disp2)
MsgBox % s . "完成载入" ie.Document.title " @ " url
ie.Quit()
ExitApp
}