GroupAdd

增加窗口规格到窗口组, 必要时创建组.

GroupAdd, GroupName , WinTitle, WinText, Label, ExcludeTitle, ExcludeText

参数

GroupName

用来保存这种窗口规格的组名. 如果组不存在, 则它会被创建. 组名不区分大小写.

WinTitle

窗口标题或识别目标窗口的其他条件. 请参阅 WinTitle.

WinText

如果使用此参数, 那么它必须是目标窗口中单个文本元素的子字符串(和内置的 Window Spy 工具显示的一样). 在使用 GroupActivate, GroupDeactivateGroupClose 时如果 DetectHiddenText 的设置为 ON, 那么会检测到隐藏文本元素.

标签

当使用 GroupActivate 命令时, 如果没有找到匹配这个组(在 [AHK_L 54] 之前为 窗口规格) 的窗口时运行的子程序标签. 跳到此标签就像使用 Gosub 一样. 如果不使用, 则请省略或留空.

ExcludeTitle

标题中含有此参数值的窗口将被排除.

ExcludeText

文本中含有此参数值的窗口将被排除.

备注

每使用此命令一次则添加一条新规则到组中. 换句话说, 一个组由窗口规格的集合组成而不是固定的窗口列表. 后面当类似 GroupActivate 的命令使用组时, 会使用这些规则中的每一条检查桌面上的每个窗口. 如果一个窗口匹配组里的其中一条规则, 则它被视为一个匹配.

尽管 SetTitleMatchModeDetectHiddenWindows 不会直接影响此命令的行为, 但它们会影响其他组命令(例如 GroupActivateGroupClose). 它们还会影响其他任何命令的 WinTitle 参数中 ahk_group 的使用.

窗口组的典型用法是将相关窗口收集绑定在一起, 这可用于包含许多相关窗口的任务或有许多子窗口的程序. 例如, 如果您频繁地工作在一个图形程序或文本编辑器的多个实例时, 您可以使用热键通过 GroupActivate 来切换此程序的每一个实例(每次一个), 而不需要使用 alt-tab 或任务栏按钮找到它们.

由于每组中的条目仅需要添加一次, 所以此命令通常使用在自动执行段中(脚本的顶部). 添加重复的条目到组中会被忽略.

要在一个组中包含 所有 窗口(除了特殊的 Program Manager 窗口), 请使用这个例子:

GroupAdd, AllWindows

通过在 WinTitle 参数中指定 ahk_group MyGroupName, 所有的窗口命令都可以操作窗口组. 命令 WinMinimize, WinMaximize, WinRestore, WinHide, WinShow, WinCloseWinKill 会对一个组中的 所有 窗口进行操作. 要仅对顶层窗口进行操作, 请参照此例:

WinHide % "ahk_id " . WinExist("ahk_group MyGroup")

与之相比, 其他的窗口命令(例如 WinActivateWinExist() / IfWinExist()) 只对组中的顶层窗口进行操作.

相关

GroupActivate, GroupDeactivate, GroupClose

示例

#1

; 在脚本顶部的自动执行段:
GroupAdd, MSIE, ahk_class IEFrame ; 只添加 Internet Explorer 窗口到该组.
return ; 自动执行段结束.

; 设置一个热键激活该组, 它会遍历
; 打开的所有 MSIE 窗口, 每次一个
; (即每次使用热键时激活一个窗口).
Numpad1::GroupActivate, MSIE, r

#2: 这是用于 MS Outlook 2002 的更复杂的组.

; 在脚本顶部的自动执行段:
SetTitleMatchMode, 2 
GroupAdd, mail, Message - Microsoft Word ; 用于当前正在编写的邮件
GroupAdd, mail, - Message ( ; 用于已打开的项目
; 需要附加文本以避免激活错误窗口:
GroupAdd, mail, Advanced Find, Sear&ch for the word(s)
GroupAdd, mail, , Recurrence: 
GroupAdd, mail, Reminder 
GroupAdd, mail, - Microsoft Outlook 
return  ; 自动执行段结束.

Numpad5::GroupActivate, mail ; 设置一个热键用于激活每个 Outlook 窗口(每次一个).