WinGetControls

返回指定窗口中所有控件的an array of names (ClassNNs).

ClassNNs := WinGetControls(WinTitle, WinText, ExcludeTitle, ExcludeText)

参数

WinTitle, WinText, ExcludeTitle, ExcludeText

类型: 字符串, 整数或对象

如果这些都是空白或省略, 将使用上次找到的窗口. 否则, 为 WinTitle 指定窗口标题或其他条件, 来标识目标窗口, 和/或为 WinText 指定目标窗口的单个文本元素的子字符串(由包含的 Window Spy 实用程序显示).

ExcludeTitle 和 ExcludeText 可用于根据标题或文本排除一个或多个窗口. 它们的规范类似于 WinTitle 和 WinText, 除了 ExcludeTitle 不识别除窗口标题之外的任何条件.

窗口标题和文本是区分大小写的. 默认情况下, 不检测隐藏窗口, 而检测隐藏文本元素, 除非使用 DetectHiddenWindows 和 DetectHiddenText 进行更改. 默认情况下, 窗口标题的任意位置包含 WinTitle 或 ExcludeTitle 就能形成匹配, 除非使用 SetTitleMatchMode 进行了更改.

返回值

类型: Array

此函数返回指定窗口中所有控件的名称的数组. 每个名称由控件的类名紧接着其序号(ClassNN) 组成, 如 Window Spy 所示.

例如, 如果将返回值赋值给名为 ClassNNs 的变量, 并且存在两个控件, 则 ClassNNs[1] 包含第一个控件的名称, ClassNNs[2] 包含第二个控件的名称, 而 ClassNNs.Length 返回该数字 2.

控件是按照 Z 轴顺序排序的, 如果窗口支持 Tab 键, Z 轴顺序通常与通过 Tab 导航的顺序相同.

错误处理

如果找不到窗口, 则抛出 TargetError.

备注

鼠标光标下的窗口或控件的 ID 可以使用 MouseGetPos 来获取.

相关

WinGetControlsHwnd, 窗口函数, 控件函数

示例

for n, ctrl in WinGetControls("A")
{
    Result := MsgBox("Control #" n " is '" ctrl "'. Continue?",, 4)
    if (Result = "No")
        break
}

SetTimer WatchActiveWindow, 200

WatchActiveWindow()
{
    try
    {
        Controls := WinGetControls("A")
        ControlList := ""
        for ClassNN in Controls
            ControlList .= ClassNN . "`n"
        if (ControlList = "")
            ToolTip "The active window has no controls."
        else
            ToolTip ControlList
    }
    catch TargetError
        ToolTip "No visible window is active."
}